Zork

An interactive fiction by Infocom -- Ported by Dean Menezes (1979) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text		Part 6 - Deep Ravine, Rocky Crawl, Egyptian Area

West of Deep Ravine is west of a dungeon called Rocky Crawl.
The description of Rocky Crawl is "This is a crawlway with a three-foot high ceiling. Your footing is very unsure here due to the assortment of rocks underfoot. Passages can be seen in the east, west, and northwest corners of the passage."
East of a dungeon called Dome Room is east of Rocky Crawl. "You are at the periphery of a large dome, which forms the ceiling of another room below. Protecting you from a precipitous drop is a wooden railing which circles the dome."
Check jumping while in Dome Room:
fatally leap instead.
A dungeon called Torch Room is down from Dome Room. "This is a large room with a prominent doorway leading to a down staircase. To the west is a narrow twisting tunnel, covered with a thin layer of dust. Above you is a large dome painted with scenes depicting elfin hacking rites. Up around the edge of the dome (20 feet up) is a wooden railing. In the center of the room there is a white marble pedestal."
The railing is unevenly shaped.
The railing is a thing in Dome Room. After tying the rope to the railing: say "The rope drops over the side and comes within ten feet of the floor."; move the coil of rope to Dome Room.
Check climbing the rope when the coil of rope is attached to the railing:
try going down instead.
The railing is scenery.
Check going down from Dome Room when the coil of rope is not attached to the railing:
say "You cannot go down without breaking many bones." instead.
Up from Torch Room is nowhere.
Check going up from Torch Room: say "You cannot reach the rope." instead.
An ivory torch is in Torch Room. The initial appearance of the ivory torch is "Sitting on the pedestal is a flaming torch, made of ivory."
The ivory torch is flaming.
The size of the ivory torch is 20.
The case-points of the ivory torch is 14.
After taking the ivory torch for the first time:
award 6 points; continue the action.
The ivory torch is lit.
Down from Torch Room is North-South Crawlway. Up from North-South Crawlway is nowhere.
Up from Torch Room is nowhere.
Rule for writing a paragraph about a rope (called the coil) when the coil is attached to something:
if the coil is attached to the railing begin;
say "Hanging down from the railing is a rope which ends about ten feet from the floor below.";
else;
say "There is [a coil] here[if the coil is attached to a visible nonrope thing], tied to [the list of nonrope visible things which are attached to the coil][end if].";
end if.
West of Torch Room is a dungeon called Tiny Room. The description of Tiny Room is "This is a tiny room, which has an exit to the east."

The initial appearance of the massive wooden door is "On the [way through the massive wooden door] side of the room is a massive wooden door, near the top of which, in the center, is a window barred with iron. A formidable bolt lock is set within the door frame. A keyhole lies within the lock[if the keyhole is closed]covered by a thin metal lid lies within the lock.[otherwise].[end if]"

A container called a keyhole is a thing. The keyhole is closed and openable.
When play begins:
now the keyhole is part of the massive wooden door.
To decide what direction is the way through (frame - a door):
let far side be the other side of frame;
let way be the best route from the location to the far side, using even locked doors;
if way is a direction, decide on the way;
decide on inside.
Understand "lid" as the keyhole.
After closing the keyhole:
say "The lid falls to cover the keyhole."
After opening the keyhole:
say "The lid opens."
Check inserting something into the keyhole when something is in the keyhole:
say "The keyhole is occupied." instead.
Before locking or unlocking the massive wooden door with something:
if something is in the keyhole, say "The keyhole is blocked." instead.
The capacity of the keyhole is 12.
A rusty iron key is a thing. The rusty iron key unlocks the massive door.
Before turning the rusty iron key:
if the iron key is in the massive door, try unlocking the massive door with the iron key instead.
Check going inside while in Tiny Room: try going north instead.
Check exiting while in Dreary Room: try going south instead.
After inserting something into the keyhole:
if the noun is the stick or the noun is the screwdriver or the noun is the set of keys and the rusty key is in Moby Lossage begin;
say "There is a faint noise from behind the door and a small cloud of
dust rises from beneath it.";
now the rusty iron key is on the mat;
now the rusty iron key is touched;
else;
continue the action;
end if.

The massive wooden door is a door. North of Tiny Room is the massive wooden door. North of the massive wooden door is a dungeon called Dreary Room. The description of Dreary Room is "This is a small and rather dreary room, which is eerily illuminated
by a red glow emanating from a crack in one of the walls. The light
appears to focus on a dusty wooden table in the center of the room."
The massive wooden door is closed,openable, locked, and lockable.

A blue crystal sphere is a thing in Dreary Room.
The description of the blue crystal sphere is "[blue sphere text]".
The case-points of the blue crystal sphere is 10.
After taking the blue crystal sphere for the first time:
award 5 points; continue the action.
To say blue sphere text:
if the red crystal sphere is in something which is closed and opaque begin;
say "You see only darkness.";
else;
say "As you peer into the sphere, a strange vision takes shape of
a distant room, which can be described clearly....[paragraph break]";
say "[description of the location of the red crystal sphere][paragraph break]";
say "The vision fades, revealing only an ordinary crystal sphere.";
end if.
Understand "PALANTHIR" and "STONE" and "SEEING" and "GLASS" and "BALL" as the white crystal sphere.
After reading a command:
if the player's command includes "BALLS/PALANTHIRI/PALANTHIRS/SPHERES", replace the matched text with "BOTH SPHERE".


Northwest of Low Crawl is east of a dungeon called Egyptian Room.
The description of Egyptian Room is "This is a room which looks like an Egyptian tomb. There is an ascending staircase in the room as well as doors east and south."
A closed openable container called a gold coffin is in Egyptian Room.
The later appearance of the gold coffin is "The solid-gold coffin used for the burial of Ramses II is here."
The size of the coffin is 55. The capacity of the coffin is 35.
After taking the coffin for the first time: award 3 points; continue the action.
The case-points of the coffin is 7.
Check going east from Egyptian Room when the player is carrying the coffin:
say "The passage is too narrow to accomodate coffins." instead.
Check going northwest from Rocky Crawl when the player is carrying the coffin:
say "The passage is too narrow to accomodate coffins." instead.
Check going south from Reservoir South when the player is carrying the coffin:
say "The coffin will not fit through this passage." instead.