Zork

An interactive fiction by Infocom -- Ported by Dean Menezes (1979) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text

Part 8 - Exorcism Stuff

North of Mirror Room No 1 is southwest of Narrow Crawlway.
Cave1 is a dungeon. "This is a tiny cave with entrances west and north, and a dark, forbidding staircase leading down."
The printed name of Cave1 is "Tiny Cave".
North of Cave1 is Narrow Crawlway. East of Mirror Room is Cave1.
Entrance to Hades is a dungeon. The description of Entrance to Hades is
"You are outside a large gateway, on which is inscribed: [paragraph break]
[8 spaces]'Abandon every hope, all ye who enter here.'[paragraph break]
The gate is open; through it you can see a desolation, with a pile of mangled corpses in one corner. Thousands of voices, lamenting some hideous fate, can be heard."
Down from Cave1 is Entrance to Hades. Land of the Living Dead is a dungeon. East of Entrance to Hades is Land of the Living Dead.
The description of Land of the Living Dead is "You have entered the Land of the Living Dead, a large desolate room. Although it is apparently uninhabited, you can hear the sounds of thousands of lost souls weeping and moaning. In the east corner are
stacked the remains of dozens of previous adventurers who were less
fortunate than yourself. To the east is an ornate passage,
apparently recently constructed. A passage exits to the west."
East of the Land of the Living Dead is a dungeon called Tomb of the Unknown Implementor. The description of Tomb of the Unknown Implementor is "This is the Tomb of the Unknown Implementer. A hollow voice says: 'That's not a bug, it's a feature!'
In the north wall of the room is the Crypt of the Implementers. It is made of the finest marble, and apparently large enough for four headless corpses. The crypt is [if the crypt is open]open[otherwise]closed[end if]. Above the entrance is the cryptic instruction: 'Feel Free'.".
Check going inside while in Tomb of the Unknown Implementor: try entering the crypt door instead.

The crypt door is a door. The crypt door is closed. The crypt door is north of the Tomb of the Unknown Implementor. The Crypt of the Implementors is a dark room. The Crypt of the Implementors is north of the crypt door. The description of the Crypt of the Implementors is "Though large and aesthetically pleasing the marble crypt is empty; the sarcophagi, bodies, and rich treasure to be expected in a tomb of this magnificence are missing. Inscribed on one wall is the motto of the implementers, 'Feel Free'. There is a door leading out of the crypt to the south. The door is [if the crypt is open]open[otherwise]closed[end if].".
Check opening the crypt door when the score is less than 616:
say "Although the implementers are dead, they foresaw that some cretin
would tamper with their remains. Therefore, they took steps to
punish such actions.";
say "Unfortunately, we've run out of poles. Therefore, in punishment for
your most grievous sin, we shall deprive you of all your valuables,
and of your life.";
end the game in death instead.
Every turn when the player is in Crypt of the Implementors:
if in darkness for the first turn begin;
say "Suddenly, as you wait in the dark, you begin to feel somewhat
disoriented. The feeling passes, but something seems different.
As you regain your composure, the cloaked figure appears before you,
and says, 'You are now ready to face the ultimate challenge of
Zork. Should you wish to do this somewhat more quickly in the
future, you will be given a magic phrase which will at any time
transport you by magic to this point. To select the phrase, say
INCANT '<word>'
and you will be told your own magic phrase to use by saying
INCANT '<word> <phrase>'
Good luck, and choose wisely!'";
end if.
Exorcism flag is a number that varies.
Check going east from Entrance to Hades when exorcism flag is not -1:
say "Some invisible force prevents you from passing through the gate." instead.
Check ringing the bell while in Entrance to Hades:
if exorcism flag is 0 begin;
say "Ding Dong.[paragraph break]";
say "The bell suddenly becomes red hot and falls to the ground. The
wraiths, as if paralyzed, stop their jeering and slowly turn to face
you. On their ashen faces, the expression of a long-forgotten terror
takes shape.";
if the candles are flaming begin;
try silently dropping the candles;
say "In your confusion, the candles drop to the ground (and they are out).";
end if;
move the brass bell to the location;
change exorcism flag to 1 instead;
else if exorcism flag is -1;
continue the action;
else;
say "The tension of this ceremony is broken, and the wraiths, amused but
shaken at your clumsy attempt, resume their hideous jeering.";
change exorcism flag to 0 instead;
end if.

Check examining the black book while in Entrance to Hades:
if exorcism flag is 2 begin;
say "[description of the black book][paragraph break]";
say "Each word of the prayer reverberates through the hall in a deafening
confusion. As the last word fades, a voice, loud and commanding,
speaks: 'Begone, fiends!'. A heart-stopping scream fills the cavern,
and the spirits, sensing a greater power, flee through the walls.";
change exorcism flag to -1 instead;
else if exorcism flag is 1;
continue the action;
else;
say "[description of the black book][paragraph break]";
say "The tension of this ceremony is broken, and the wraiths, amused but
shaken at your clumsy attempt, resume their hideous jeering." instead;
end if.
The description of the crypt door is "Here lie the implementers, whose heads were placed on poles by the Keeper of the Dungeon for amazing untastefulness." The crypt door is scenery.
A set of poled heads is in the Tomb of the Unknown Implementors. The set of poled heads is not portable. The initial appearance of the set of poled heads is "There are four heads here, mounted securely on poles." Understand "HEADS" and "HEAD" and "POLE" and "POLES" and "PDL" and "BKD" and "TAA" and "MARC" and "IMPLEMENTORS" and "LOSER" as the set of poled heads.
Instead of taking or destroying or attacking or kicking or poking the set of poled heads:
say "Although the implementers are dead, they foresaw that some cretin
would tamper with their remains. Therefore, they took steps to
punish such actions.";
say "Unfortunately, we've run out of poles. Therefore, in punishment for
your most grievous sin, we shall deprive you of all your valuables,
and of your life.";
end the game in death.
Check destroying the set of poled heads with something:
say "Although the implementers are dead, they foresaw that some cretin
would tamper with their remains. Therefore, they took steps to
punish such actions.";
say "Unfortunately, we've run out of poles. Therefore, in punishment for
your most grievous sin, we shall deprive you of all your valuables,
and of your life.";
end the game in death instead.
Check attacking the set of poled heads with something:
try destroying the set of poled heads with the second noun instead.
The rval of Land of the Living Dead is 30.

In the Tomb of the Unknown Implementor is a bunch of Coke bottles. The initial appearance of the bunch of Coke bottles is "There is a large pile of empty Coke bottles here, evidently produced by the implementers during their long struggle to win totally."
The later appearance of the bunch of Coke bottles is "Many empty Coke bottles are here. Alas, they can't hold water."
The size of the bunch of Coke bottles is 15.
In the Tomb of the Unknown Implementor is a stack of listings. The description of the stack of listings is "[listing text]".
To say listing text:
say "<DEFINE FEEL-FREE (LOSER)[line break]";
say " <TELL 'FEEL FREE, CHOMPER!'>>[line break]";
say " ...[line break]";
say "The rest is, alas, unintelligible (as were the implementers)."
The size of the stack of listings is 70. The initial appearance of the stack of listings is
"There is a gigantic pile of line-printer output here. Although the
paper once contained useful information, almost nothing can be
distinguished now."
The later appearance of the stack of listings is "There is an enormous stack of line-printer paper here. It is barely readable."
The listings are inflammable.
Check destroying the bunch of Coke bottles:
say "Congratulations! You've managed to break all those bottles.
Fortunately for your feet, they were made of magic glass and disappear
immediately.";
remove the bunch of Coke bottles from play instead.
Check destroying the bunch of Coke bottles with something:
say "Congratulations! You've managed to break all those bottles.
Fortunately for your feet, they were made of magic glass and disappear
immediately.";
remove the bunch of Coke bottles from play;
say "Somehow, [the second noun] managed to disappear as well.";
remove the second noun from play instead.
Check throwing the bunch of Coke bottles at something:
say "Congratulations! You've managed to break all those bottles.
Fortunately for your feet, they were made of magic glass and disappear
immediately.";
remove the bunch of Coke bottles from play;
say "Somehow, [the second noun] managed to disappear as well.";
remove the second noun from play instead.
Check dropping bunch of Coke bottles when the player's command includes "throw":
say "Congratulations! You've managed to break all those bottles.
Fortunately for your feet, they were made of magic glass and disappear
immediately.";
remove the bunch of Coke bottles from play instead.

Dead flag is a truth state variable. Dead flag is usually false.

East of Ravine is a dungeon called Chasm. The description of Chasm is "A chasm runs southwest to northeast. You are on the south edge; the path exits to the south and to the east."
Check going down from Chasm:
say "Are you out of your mind?" instead.
Check jumping while in Chasm: fatally leap instead.

Northeast of Round Room is south of a dungeon called North-South Passage. The description of North-South Passage is "This is a high north-south passage, which forks to the northeast."
North of North-South Passage is east of Chasm. Northeast of North-South Passage is west of a dungeon called Loud Room. The description of Loud Room is "This is a large room with a ceiling which cannot be detected from the ground. There is a narrow passage from east to west and a stone stairway leading upward. The room is extremely noisy. In fact, it is difficult to hear yourself think."

Echo flag is a truth state variable. Echo flag is usually false.
After reading a command while in Loud Room:
if the player's command does not include "[direction]" and the player's command does not match "ECHO" and echo flag is false begin;
say "[player's command]";
reject the player's command;
else if the player's command matches "ECHO" and echo flag is false;
change echo flag to true;
say "The acoustics of the room change subtly.";
reject the player's command;
end if.
A large platinum bar is in Loud Room. The printed name of the large platinum bar is "platinum bar". The later appearance of the large platinum bar is "There is a large platinum bar here." The size of the platinum bar is 20. The case-points of the platinum bar is 10.
After taking the platinum bar for the first time:
award 12 points; continue the action.
Up from Loud Room is south of a dungeon called Damp Cave. The description of Damp Cave is "This is a cave. Passages exit to the south and to the east, but the cave narrows to a crack to the west. The earth is particularly damp here."
Check going west from Damp Cave: say "It is too narrow for most insects." instead.
East of Loud Room is south of a dungeon called Ancient Chasm. The description of Ancient Chasm is "A chasm, evidently produced by an ancient river, runs through the
cave here. Passages lead off in all directions."
North of Ancient Chasm is southeast of a dead end. West of Ancient Chasm is a dead end.
East of Ancient Chasm is northwest of a dungeon called Tiny Cave. The description of Tiny Cave is "This is a small cave whose exits are on the south and northwest."
A hunk of bat guano is in Tiny Cave. Understand "excretement" and "shit" and "crap" and "poop" as the bat guano.
The size of the bat guano is 20.
A shovel is in Tiny Cave. The later appearance of the shovel is "There is a large shovel here." Understand "large shovel" as the shovel. The size of the shovel is 15.