Zork

An interactive fiction by Infocom -- Ported by Dean Menezes (1979) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text

Part 9 - Coal Mine Area

Mirror Room No 2 is a dungeon. The printed name of Mirror Room No 2 is "Mirror Room". The description of Mirror Room No 2 is "This is a large square room with tall ceilings. On the south wall is a gigantic mirror which fills the entire wall. There are exits on the other three sides of the room."
An gigantic mirror is in Mirror Room No 2. It is scenery.
The description of the gigantic mirror is "[if the gigantic mirror is whole]There is an ugly person staring back at you.[otherwise]The mirror is broken into many pieces.[end if]".
Instead of touching or rubbing the gigantic mirror:
say "There is a rumble from deep within the earth and the room shakes.";
move the player to Mirror Room No 1.
West of Mirror Room No 2 is a dungeon called Cold Passage. The description of Cold Passage is "This is a cold and damp corridor where a long east-west passageway intersects with a northward path."
North of Cold Passage is southwest of a dungeon called Steep Crawlway. The description of Steep Crawlway is "This is a steep and narrow crawlway. There are two exits nearby to
the south and southwest."
South of Steep Crawlway is Mirror Room No 2.
East of Mirror Room No 2 is north of a dungeon called Cave2. The printed name of Cave2 is "Tiny Cave". The description of Cave2 is "This is a tiny cave with entrances west and north, and a dark, forbidding staircase leading down."
Down from Cave2 is a dungeon called Atlantis Room. The description of Atlantis Room is "This is an ancient room, long under water. There are exits here to the southeast and upward."
Southeast of Atlantis Room is north of a dungeon called Reservoir North. A drainable watersource called the pdl3 is in Reservoir North. The description of Reservoir North is "[if the pdl3 is on-stage]You are in a large cavernous room, north of a large reservoir.[otherwise]You are in a large cavernous room, the south of which was formerly a reservoir.[end if] There is a tunnel leaving the room to the north."
A nondrainable watersource called the pdl4 is in Reservoir. Down from In Stream is Reservoir.
Check going southeast from Atlantis Room: move the player to Reservoir North instead.
A crystal trident is in Atlantis Room. The initial appearance of the crystal trident is "On the shore lies Poseidon's own crystal trident." The later appearance of the crystal trident is "Poseidon's own crystal trident is here." The size of the crystal trident is 20. The case-points of the crystal trident is 11. After taking the crystal trident for the first time: award 4 points; continue the action.
West of Cold Passage is a dungeon called Slide Room. The description of Slide Room is "This is a small chamber, which appears to have been part of a coal mine. On the south wall of the chamber the letters 'Granite Wall' are etched in the rock. To the east is a long passage and there is a steep metal slide twisting downward. To the north is a small opening."

The enormous mirror can be whole or trashed. The gigantic mirror can be whole or trashed.
The enormous mirror is whole. The gigantic mirror is whole.
Check destroying the enormous mirror:
if the enormous mirror is trashed begin;
say "It's already broken." instead;
else if the gigantic mirror is trashed;
say "Haven't you done enough damage already?" instead;
else;
now the enormous mirror is trashed;
say "You have broken the mirror. I hope you have a seven years supply of
good luck handy." instead;
end if.
Check destroying the gigantic mirror:
if the gigantic mirror is trashed begin;
say "It's already broken." instead;
else if the enormous mirror is trashed;
say "Haven't you done enough damage already?" instead;
else;
now the gigantic mirror is trashed;
say "You have broken the mirror. I hope you have a seven years supply of
good luck handy." instead;
end if.
Check taking the enormous mirror:
if the enormous mirror is trashed, say "Nobody but a greedy surgeon would allow you to attempt that trick." instead.
Check taking the gigantic mirror:
if the enormous mirror is trashed, say "Nobody but a greedy surgeon would allow you to attempt that trick." instead.
The long slide is a door. The long slide is open and unopenable. The long slide is down from Slide Room. The long slide is scenery. Down from the Long Slide is Cellar.

Check going through the long slide:
if the coil of rope is attached to something in Slide Room, move the player to Slide1 instead.

Before climbing the rope:
if the coil of rope is attached to the coffin or the coil of rope is attached to the timber and the rope is in Slide Room, try going down instead.

Sllide1 is a dark room. The printed name of Slide1 is "Slide". The description of Slide1 is "This is an uncomfortable spot within the coal chute. The rope to which you are clinging can be seen rising into the darkness above. There is more rope dangling below you."

Up from Slide1 is Slide Room.
Down from Slide1 is a dark room called Slide2. The printed name of Slide2 is "Slide". The description of Slide2 is "This is another spot within the coal chute. Above you the rope
climbs into darkness and the end of the rope is dangling five feet beneath you."

Down from Slide2 is a dark room called Slide3. The printed name of Slide3 is "Slide". The description of Slide3 is "You have reached the end of your rope. Below you is darkness as
the chute makes a sharp turn. On the east here is a small ledge which you might be able to stand on."

Down from Slide3 is Cellar.
East of Slide3 is a dark room called Slide Ledge. The description of Slide Ledge is "This is a narrow ledge abutting the coal chute, in which a rope can be seen passing downward. Behind you, to the south, is a small room."
West of Slide Ledge is nowhere.
Down from Slide Ledge is Cellar.
South of Slide Ledge is a dark room called Sooty Room. The description of Sooty Room is "This is a small room with rough walls, and a ceiling which is steeply
sloping from north to south. There is coal dust covering almost
everything, and little bits of coal are scattered around the only exit
(which is a narrow passage to the north). In one corner of the room is
an old coal stove which lights the room with a cheery red glow. There
is a very narrow crack in the north wall."
Check exiting while in Sooty Room:
try going north instead.
A red crystal sphere is in Sooty Room. The initial appearance of the crystal sphere is "On the floor sits a red crystal sphere." The later appearance of the crystal sphere is "There is red crystal sphere here."
Understand "PALANTHIR" and "STONE" and "SEEING" and "GLASS" and "BALL" as the white crystal sphere.
The case-points of the red crystal sphere is 10. After taking the red crystal sphere: award 5 points; continue the action.

The description of the red crystal sphere is "[red sphere text]".
To say red sphere text:
if the white crystal sphere is in something which is closed and opaque begin;
say "You see only darkness.";
else;
say "As you peer into the sphere, a strange vision takes shape of
a distant room, which can be described clearly....[paragraph break]";
say "[description of the location of the white crystal sphere][paragraph break]";
say "The vision fades, revealing only an ordinary crystal sphere.";
end if.
Check searching the blue crystal sphere: try examining the noun instead.
North of Slide Room is a dungeon called Mine Entrance. The description of Mine Entrance is "You are standing at the entrance of what might have been a coal
mine. To the northeast and the northwest are entrances to the mine,
and there is another exit on the south end of the room."
Northwest of Mine Entrance is south of a dungeon called Squeaky Room. The description of Squeaky Room is "You are a small room. Strange squeaky sounds may be heard coming from
the passage at the west end. You may also escape to the south."
West of Squeaky Room is a dungeon called Bat Room. The description of Bat Room is "You are in a small room which has only one door, to the east. In the corner of the room on the ceiling is a large vampire bat who is obviously deranged and holding his nose."
Instead of going west from Bat Room when dead flag is false and when the player is not holding the garlic:
say "A deranged giant vampire bat (a reject from WUMPUS) swoops down
from his belfry and lifts you away....";
move the player to a random coal mine.
A coal mine is a kind of dungeon. A coal mine usually has printed name "Coal Mine". A coal mine usually has description "This is a non-descript part of a coal mine."
A deranged giant vampire bat is in Bat Room. The deranged giant vampire bat is scenery. Check taking the deranged giant vampire bat:
say "A deranged giant vampire bat (a reject from WUMPUS) swoops down
from his belfry and lifts you away....";
move the player to a random coal mine instead.
A jade figurine is in Bat Room. The size of the jade figurine is 10. The case-points of the jade figurine is 5. After taking the jade figurine for the first time: award 5 points.
Northeast of Mine Entrance is west of a dungeon called Shaft Room. The description of Shaft Room is "This is a large room, in the middle of which is a small shaft
descending through the floor into darkness below. To the west and
the north are exits from this room. Constructed over the top of the
shaft is a metal framework to which a heavy iron chain is attached."
A container called the tbasket is in Shaft Room. The printed name of the tbasket is "basket". The later appearance of the tbasket is "At the end of the chain is a basket." The capacity of the tbasket is 50. Understand "dumbwaiter" and "cage" and "basket" as the tbasket. The tbasket is fixed in place.
Lower Shaft is a dark room. The description of Lower Shaft is
"This is a small square room which is at the bottom of a long
shaft. To the east is a passageway and to the northeast a very narrow
passage. In the shaft can be seen a heavy iron chain."
A thing called the fbasket is in Lower Shaft. The fbasket is scenery. Understand "basket" and "dumbwaiter" and "cage" as the fbasket.
Instead of going down while in Shaft Room: say "You wouldn't fit and would die if you could."
After deciding the scope of the player when in darkness:
if the fbasket is in the location, place the fbasket in scope;
if the tbasket is in the location, place the tbasket in scope.
North of Shaft Room is a dungeon called Wooden Tunnel. The description of Wooden Tunnel is "This is a narrow tunnel with large wooden beams running across
the ceiling and around the walls. A path from the south splits into
paths running west and northeast."
West of Wooden Tunnel is a dungeon called Smelly Room. The description of Smelly Room is "This is a small non-descript room. However, from the direction
of a small descending staircase a foul odor can be detected. To the
east is a narrow path."
Down from Smelly Room is a dark room called Gas Room. The description of Gas Room is "This is a small room which smells strongly of coal gas."
A sapphire bracelet is in Gas Room. The later appearance of the sapphire bracelet is "There is a sapphire-encrusted bracelet here."
The sapphire bracelet is wearable. The size of the bracelet is 10. The case-points of the bracelet is 3. After taking the bracelet for the first time: award 5 points; continue the action.
Every turn when the player is in Gas Room and dead flag is false:
if the player is carrying the ivory torch and the ivory torch is lit begin;
say "Oh dear. It appears that the smell coming from this room was coal gas. I would have thought twice about carrying a torch in here.";
end the game in death;
end if.

Northeast of Wooden Tunnel is east of a coal mine called Mine1.
Southwest of Mine1 is south from a coal mine called Mine2.
Up from Mine2 is west of a coal mine called Mine3.
Northeast of Mine2 is west of a coal mine called Mine4.
North of Mine1 is Mine4.
Northeast of Mine3 is up from a coal mine called Mine5.
East of Mine3 is south of Mine5.
West of Mine2 is west of Mine5.
East of Mine5 is up from Mine4.
Northeast of Mine4 is southeast of a coal mine called Mine6.
Up from Mine6 is Mine5.
North of Mine5 is west of a coal mine called Mine7.
South of Mine7 is northwest of Mine6.
East of Mine7 is Mine1.
Down from Mine7 is a dungeon called Ladder Top.
The description of Ladder Top is "This is a very small room. In the corner is a rickety wooden
ladder, leading downward. It might be safe to descend. There is
also a staircase leading upward."
Down from Ladder Top is a dungeon called Ladder Bottom.
The description of Ladder Bottom is "This is a rather wide room. On one side is the bottom of a narrow wooden ladder. To the northeast and the south are passages
leaving the room."
Northeast of Ladder Bottom is south of a dead end called DE2. A pile of coal is in DE2. Understand "heap" and "small" as the pile of coal. The later appearance of the pile of coal is "There is a small heap of coal here."
The coal is inflammable.
South of Ladder Bottom is north of a dark room called Timber Room. The description of Timber Room is "This is a long and narrow passage, which is cluttered with broken
timbers. A wide passage comes from the north and turns at the
southwest corner of the room into a very narrow passageway."
An unevenly shaped thing called a broken timber is in Timber Room. Understand "pile" and "wooden" as the broken timber. The size of the broken timber is 50.
The later appearance of the broken timber is "There is a wooden timber on the ground here."
The narrow passageway is a door. The narrow passageway is open and unopenable. Inside from Timber Room is the narrow passageway. Outside from Lower Shaft is the narrow passageway.
Check going southwest while in Timber Room: try going inside instead.
Check going northeast while in Lower Shaft: try going outside instead.
Before of going through the narrow passageway when the player is carrying something: say "You cannot fit through this passage with that load." instead.
Check going up from Lower Shaft: say "The chain is not climbable." instead.
East of lower shaft is northwest of a dark room called Machine2 Room. The printed name of Machine2 Room is "Machine Room".
The description of Machine2 Room is "This is a large room which seems to be air-conditioned. In one corner there is a machine (?) which is shaped somewhat like a clothes dryer. On the 'panel' there is a switch which is labelled in a dialect of Swahili. Fortunately, I know this dialect and the label translates to START. The switch does not appear to be manipulable by any human hand (unless the fingers are about 1/16 by 1/4 inch). On
the front of the machine is a large lid, which is [if the machine is open]open[otherwise]closed[end if]."
The PDP-10 is a closed openable container in Machine2 Room. The PDP-10 is scenery. A thing called the switch is part of the PDP-10. The printed name of the PDP-10 is "lid".
Understand "dryer" and "pdp10" and "vax" and "machine" and "lid" as the PDP-10.
Check turning the switch:
say "You'll cannot manipulate the switch with your hands." instead.
Carry out turning the switch with something:
if the second noun is not the screwdriver begin;
say "It seems that [a second noun] won't do.";
else if the PDP-10 is open;
say "The machine doesn't seem to want to do anything.";
else;
say "The machine comes to life (figuratively) with a dazzling display of colored lights and bizarre noises. After a few moments, the excitement abates.";
if the pile of coal is in the PDP-10 begin;
remove the junk;
now the diamond is in the PDP-10;
else if the diamond is in the PDP-10;
do nothing;
else;
remove the junk;
now the piece of vitreous slag is in the PDP-10;
end if;
end if.
To remove the junk:
repeat with thingy running through things contained by the PDP-10 begin;
remove the thingy from play;
end repeat.
A piece of vitreous slag is a thing.
Understand "gunk" as the piece of vitreous slag.
A huge diamond is a thing.
The later appearance of the huge diamond is "There is an enormous diamond (perfectly cut) here."
The case-points of the huge diamond is 6. Understand "enormous" as the huge diamond.
After taking the huge diamond for the first time:
award 10 points; continue the action.
Check taking the slag: say "The slag turns out to be rather insubstantial, and crumbles into dust at your touch. It must not have been very valuable." instead.
The capacity of the PDP-10 is 50.