Zork

An interactive fiction by Infocom -- Ported by Dean Menezes (1979) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text		Part 10 - The Reservoir

East of Deep Canyon is south of a dungeon called Flood Control Dam #3. The description of Flood Control Dam #3 is "You are standing on the top of the Flood Control Dam #3, which was quite a tourist attraction in times far distant. There are paths to the north, south, east, and down. There is a control panel here. There is a large metal bolt on the panel. Above the bolt is a small green plastic bubble. [if gate flag is true]The green bubble is glowing.[end if]".
East of Flood Control Dam #3 is east of Damp Cave.
A thing called a bolt is in Flood Control Dam #3. A thing called a bubble is in Flood Control Dam #3. The bolt and the bubble are scenery. Flood Control Dam #3 is not dark.
North of Flood Control Dam #3 is a dungeon called Dam Lobby. Dam Lobby is not dark. The description of Dam Lobby is "This room appears to have been the waiting room for groups touring the dam. There are exits here to the north and east marked 'Private', though the doors are open, and an exit to the south."
A tour guidebook is in Dam Lobby. The initial appearance of the tour guidebook is "Some guidebooks entitled 'Flood Control Dam #3' are on the reception
desk." The later appearance of the tour guidebook is "There are tour guidebooks here."
The description of the tour guidebooks is "[guidebook text]".
The guidebook is inflammable.
To say guidebook text:
center "Guide Book to";
center "Flood Control Dam #3";
say "Flood Control Dam #3 (FCD#3) was constructed in year 783 of the
Great Underground Empire to harness the destructive power of the
Frigid River. This work was supported by a grant of 37 million
zorkmids from the Central Bureaucracy and your omnipotent local
tyrant Lord Dimwit Flathead the Excessive. This impressive
structure is composed of 3.7 cubic feet of concrete, is 256 feet
tall at the center, and 193 feet wide at the top. The reservoir
created behind the dam has a volume of 37 billion cubic feet, an
area of 12 million square feet, and a shore line of 36 thousand
feet.[paragraph break]";
say "The construction of FCD#3 took 112 days from ground breaking to
the dedication. It required a work force of 384 slaves, 34 slave
drivers, 12 engineers, 2 turtle doves, and a partridge in a pear
tree. The work was managed by a command team composed of 2345
bureaucrats, 2347 secretaries (at least two of whom can type),
12,256 paper shufflers, 52,469 rubber stampers, 245,193 red tape
processors, and nearly one million dead trees.[paragraph break]";
say "We will now point out some of the more interesting features
of FCD#3 as we conduct you on a guided tour of the facilities. You start your tour here in the Dam Lobby. You will notice on your right that ........."
Match count is a number that varies. Match count is usually 5.
A matchbook is in Dam Lobby. Understand "matches" and "match" and "flint" as the matchbook. The later appearance of the matchbook is "There is a matchbook whose cover says 'Visit Beautiful FCD#3' here."
Check opening the matchbook: try counting the matchbook instead.
The description of the matchbook is "[matchbook text]".
To say matchbook text:
center "[unicode 91]close cover before striking BKD[unicode 93]";
say paragraph break;
center "YOU too can make BIG MONEY in the exciting field of";
center "PAPER SHUFFLING!";
say paragraph break;
say "Mr. TAA of Muddle, Mass. says: 'Before I took this course I used
to be a lowly bit twiddler. Now with what I learned at MIT Tech
I feel really important and can obfuscate and confuse with the best.'[paragraph break]";
say "Mr. MARC had this to say: 'Ten short days ago all I could look
forward to was a dead-end job as a doctor. Now I have a promising
future and make really big Zorkmids.'[paragraph break]";
say "MIT Tech can't promise these fantastic results to everyone. But when
you earn your MDL degree from MIT Tech your future will be brighter.[paragraph break]";
center "Send for our free brochure today".
North of Dam Lobby is west of a dungeon called Maintenance Room. East of Dam Lobby is south of Maintenance Room. The description of Maintenance Room is "This is what appears to have been the maintenance room for Flood
Control Dam #3, judging by the assortment of tool chests around the
room. Apparently, this room has been ransacked recently, for most of
the valuable equipment is gone. On the wall in front of you is a
group of buttons, which are labelled in EBCDIC. However, they are of
different colors: Blue, Yellow, Brown, and Red. The doors to this
room are in the west and south ends."
Maintenance Room is not dark.
A thing called a screwdriver is in Maintenance Room. A thing called a wrench is in Maintenance Room.
A red button, a yellow button, a blue button, and a brown button are in Maintenance Room. The red button, the blue button, the brown button, and the yellow button are scenery.
Check pushing the red button:
if Maintenance Room is not lit begin;
say "The lights within the room come on.";
now Maintenance Room is lit instead;
else;
say "The lights within the room shut off.";
now Maintenance Room is dark instead;
end if.
A closed openable container called a tube is in Maintenance Room. The later appearance of the tube is "There is an object which looks like a tube of toothpaste here."
Understand "tube of toothpaste" as the tube. The capacity of the tube is 7. The size of the tube is 10. The description of the tube is "Frobozz Magic Gunk Company: All Purpose Gunk".
Some viscous material is in the tube. Understand "gunk" and "glue" as the viscous material. The later appearance of the viscous material is "There is some gunk here.".
Instead of inserting something into the tube: say "The tube refuses to accept anything."
After taking the viscous material from the tube:
say "The viscous material oozes into your hand."
After reading a command:
if the player's command includes "squeeze [tube]", replace the matched text with "get all from [tube]".

Table of Drowning Messages
message
"up to your ankles."
"up to your shin."
"up to your knees."
"up to your hips."
"up to your waist."
"up to your chest."
"up to your neck."
"over your head."
"high in your lungs."


Water level is a number that varies. Water level is usually 0.
Understand "putty" and "toothpaste" as the viscous material.
Check pushing the blue button:
if water level is not zero begin;
say "The blue button appears to be jammed." instead;
else;
say "There is a rumbling sound and a stream of water appears to burst from the east wall of the room (apparently, a leak has occurred in a pipe.)";
change water level to 1;
move the leak2 to Maintenance Room instead;
end if.
The leak2 is a thing. The leak2 is scenery. The printed name of the leak2 is "leak".
Understand "leak" as the leak2.
Every turn when water level is greater than 0 and water level is less than 19:
increase water level by 1;
let n be water level / 2;
if the player is in Maintenance Room begin;
say "The water is [message in row n of the Table of Drowning Messages]";
if water level is 18 begin;
say " I'm afraid you have done drowned yourself.";
end the game in death;
end if;
end if.
Carry out plugging the leak2 with the viscous material:
say "By some miracle of elven technology, you have managed to stop the
leak in the dam.";
change water level to -1;
remove the leak2 from play.
Before going north from Dam Lobby when water level is greater than 17:
say "The room is full of water and cannot be entered.";
stop the action.
Before going east from Dam Lobby when water level is greater than 17:
say "The room is full of water and cannot be entered.";
stop the action.

Check pushing the brown button:
change gate flag to false;
say "Click." instead.
Check pushing the yellow button:
change gate flag to true;
say "Click." instead.
Check turning the bolt with something:
if the second noun is not the wrench, say "The bolt won't turn using [the second noun]." instead;
if gate flag is false, say "The bolt won't turn with your best effort." instead.

Gate flag is a truth state variable. Gate flag is usually false.
Carry out turning the bolt with the wrench:
if the pdl3 is on-stage begin;
say "The sluice gates open and water pours through the dam.";
repeat with thingy running through drainable watersources begin;
remove the thingy from play;
end repeat;
else;
say "The sluice gates close and water starts to collect behind the dam.";
move the pdl1 to Reservoir South;
move the pdl3 to Reservoir North;
end if.
North of Reservoir South is a dungeon called Reservoir. The description of Reservoir is
"[if the pdl3 is on-stage]You are on the reservoir. Beaches can be seen north and south. Upstream a small stream enters the reservoir through a narrow cleft
in the rocks. The dam can be seen downstream.[otherwise]You are on what used to be a large reservoir, but which is now a large mud pile. There are 'shores' to the north and south.[end if]".
North of Reservoir is Reservoir North.
Check going north from Reservoir:
move the player to Reservoir North instead.
Check going to a room that is not offroad:
if the player is not in a vehicle, print the you can't go message instead;
else continue the action.
A hand-held air-pump is in Reservoir North. Understand "pump" and "airpump" as the air-pump. The later appearance of the air-pump is "There is a small pump here."

A trunk of jewels is in Reservoir. Understand "chest" as the trunk. The size of the trunk is 35. The case-points of the trunk is 8. After taking the trunk: award 15 points; continue the action. The initial appearance of the trunk of jewels is "Lying half buried in the mud is an old trunk, bulging with jewels." The later appearance of the trunk of jewels is "There is an old trunk here, bulging with assorted jewels."